用户工具

站点工具


learing:examples:string_append_operator

String Appending Operators(字符串附加运算)

你可以使用StringAdditionOperator来合并不同的数据类型到字符串,当然也可以使用+=运算符和concat()方法来添加别的东西到字符串。+=运算符和concat()方法的工作原理是一样的,用哪种方法全凭喜好。下面的两个例子说明了这两种方法的使用,并且得到相同的字符串。

String stringOne = "A long integer: ";
  // 使用+=添加一个长整型变量到字符串
  stringOne += 123456789;
 
or
 
  String stringTwo = "A long integer: ";
 
  // 使用concat()添加长整型到字符串
  stringTwo.concat(123456789);

两种情况下,stringOne都是“A long integer: 123456789”。和+运算符一样,这些运算符很方便的从混杂的数据类型中组合得到更长的字符串

硬件要求

OCROBOT控制器
USB线

这个例子没有电路图,只需要通过USB线把你的OCROBOT控制器连上电脑,并且打开串口监视器。

ALPHA MEGA328-U核心

硬件

搭建电路

  1. USB线连接计算机与ALPHA MEGA328-U。

代码

/*
  Appending to Strings using the += operator and concat()
*/
 
String stringOne, stringTwo;
 
void setup() {
  // 打开串口通讯
  Serial.begin(9600);
  stringOne = String("Sensor ");
  stringTwo = String("value");
  // 标题:
  Serial.println("\n\nAppending to a string:");
  Serial.println();
}
 
void loop() {
  Serial.println(stringOne);  // 现实  "Sensor "
 
  // 添加一个字符串到字符串里
  stringOne += stringTwo;
  Serial.println(stringOne);  // 显示 "Sensor value"
 
  // 添加常量字符串到字符串
  stringOne += " for input ";
  Serial.println(stringOne);  // 显示  "Sensor value for input"
 
  // 添加常量字符到字符串
  stringOne += 'A';
  Serial.println(stringOne);   // 显示 "Sensor value for input A"
 
  // 添加整型常量到字符串
  stringOne += 0;
  Serial.println(stringOne);   // 现实 "Sensor value for input A0"
 
  // 添加字符串常量到字符串
  stringOne += ": ";
  Serial.println(stringOne);  // 显示 "Sensor value for input"
 
  // 添加整型变量到字符串
  stringOne += analogRead(A0);
  Serial.println(stringOne);   //显示  "Sensor value for input A0: 456" 或者其它 analogRead(A0) 值
  Serial.println("\n\nchanging the Strings' values");
  stringOne = "A long integer: ";
  stringTwo = "The millis(): ";
 
  // 添加长整型常量到字符串
  stringOne += 123456789;
  Serial.println(stringOne);   // 显示  "A long integer: 123456789"
 
  // 使用concat() 添加长整型变量到字符串
  stringTwo.concat(millis());
  Serial.println(stringTwo); // 显示  "The millis(): 43534" 或者其它的 millis() 值
 
  //循环下去:
  while (true);
}
learing/examples/string_append_operator.txt · 最后更改: 2023/06/07 04:23 由 127.0.0.1